===========================================================================
 BBS: The Abacus * HST/DS * Potterville, MI
Date: 06-03-93 (21:38)             Number: 99
From: VICTOR YIU                   Refer#: NONE
  To: ALL                           Recvd: NO  
Subj: FilterHigh 2.0 (1/4)           Conf: (35) Quick Basi
---------------------------------------------------------------------------
-----------------------------------
Use the FH.OBJ file and do this:

lib fh +fh;
link /qui fh.lib,,,\qb\bqlb45;
                       ^^^^^^--- use appropriate one...
Then you will get the QLB and the LIB file.
------------------------------------
Below is the FH.ASM...

; FilterHigh 2.0
; ~~~~~~~~~~~~~~
; Ultra-quick filtering routine, written in assembly.
;
; 1.0  John Gallas     Original release
; 2.0  Victor Yiu      ASM Version
;
; declare:
; DECLARE SUB FilterHighASM (BYVAL Segm%, BYVAL Offst%, BYVAL Leng%)

CODE SEGMENT PARA PUBLIC 'CODE'
    PUBLIC FilterHighASM
    assume cs:CODE, ds:nothing, es:nothing, ss:nothing

FilterHighASM PROC FAR

JMP NEAR Start

Table LABEL BYTE
db 0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22
db 23,24,25,26,27,28,29,30,31,' !"#$%&',39,'()*+,-./0123456789:'
db ';<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\]^_`abcdefghijklmnopqrstu'
db 'vwxyz{|}~oCueaaaaceeeiiiAAE&AooouuyOUcLY#faiounNao?++//!<>!'
db '@#|++++++|+++++++++-++++++++=+++++++++++++#v||^ab%nEeur*OOQ'
db 'oo{N=#><///=^../n2o '

EVEN
Start:
    PUSH BP
    MOV BP, SP      ; set up stack frame

    PUSH SI         ; save required registers
    PUSH DI
    PUSH DS

    MOV DX, [BP+6]  ; load # of bytes into DX
    LDS SI, [BP+8]  ; load string addresses into DS/SI
    LES DI, [BP+8]  ; and ES/DI

    MOV BX, OFFSET Table  ; point BX to the table offset for XLAT

    MOV AX, DX      ; save count into AX
    MOV CL, 4       ; 2^4 = 16, shift count
    SHR DX, CL      ; divide count by sixteen -- each loop does 16 bytes
    MOV CX, DX      ; put it into CX, the counter var.

    AND AX, 15      ; take modulo 16 of saved count
    JZ InLineStart  ; if zero, just stop counting and start

    INC CX          ; otherwise, compensate for extra pass for loop
    SHL AX, 1       ; x4 -- 4 bytes of code for each byte processed
    SHL AX, 1
    MOV DX, OFFSET InLineEnd    ; find end of in-line code
    SUB DX, AX      ; figure where to jump to
    JMP DX          ; jump!

EVEN                ; align to even addr -- faster!
InLineStart:

REPT 16             ; repeat 16 times for speed!
    LODSB           ; load byte
    XLAT [CS:BX]    ; translate
    STOSB           ; store
ENDM

InLineEnd:
LOOP InLineStart

Quit:
    POP DS          ; restore registers
    POP DI
    POP SI
    POP BP
    RET 6           ; return, shaving off 6 bytes

FilterHighASM ENDP
    CODE ENDS
END

-------8<---  Chop

BASIC & Object file in next message...


--- Blue Wave/RA v2.12 [NR]
 * Origin: Hard Disc Cafe | Houston Texas | (713) 589-2690 |  (1:106/30.0)
SEEN-BY: 1/211 11/2 4 13/13 101/1 108/89 109/25 110/69 114/5 123/19 124/1
SEEN-BY: 153/752 154/40 77 157/110 159/100 125 430 575 950 203/23 209/209
SEEN-BY: 261/1023 280/1 390/1 396/1 15 397/2 2230/100 2440/5 3603/20