Comment
==================================================================

Computer Tyme BatZap * Copyright 1994 by Marc Perkel
All Rights Reserved

Computer Tyme * 411 North Sherman, Suite 300 * Springfield Mo. 65802
(417) 866-1222 Voice * (800) 548-5353 Sales * (417) 866-1665 Fax/BBS

* We're moving! - Starting 1995 - Computer Tyme, Fair Grove Mo. 65648

This utility is a script language for modifying batch files and other
configuration files in text format.

 Usage: BATZAP <Script File>

 Example:
   BatZap AUTO.BZ   ;the BZ extension is assumed

Price $95 per Server.
Written in MarxMenu. Comes free with the Network Survival Kit.

==================================================================
EndComment

Var
  Stack
  ParenLevel
  Script
  Orig
  FileArray
  PC
  PCLine
  CurrentLine
  StartLine
  EndLine
  Section
  GroupsRead
  GroupList
  SecurityRead
  SecurityList
  FindMode
  WhereFound
  NameOfFile
  Debug
  FileAttribute
  ThisWord
  RunThis
  ErrorLevel
  NoBak


Var A B C D E F G H I J K L M N O P Q R S T U V W X Y Z


Main

;===========================================================

Procedure Error (St,Line)
   Writeln
   if Line > 0
      Writeln 'BatZap Error in Line: ' Line
      Writeln 'Line: [' Orig[Line] ']'
      Writeln St
   else
      Writeln 'BatZap Error: ' St
   endif
   ExitMenu
EndProc


Procedure UnknownCommand
   Error ('Word "' + ThisWord + '" not Recognized!',PC)
EndProc


Procedure PushStack (V)
   AppendArray(Stack,V)
EndProc


Procedure PopStack
   if NumberOfElements(Stack) = 0
      Error ('Stack Empty!',PC)
   endif
   Return PopArray(Stack)
EndProc


Procedure StackTop
var N
   N = NumberOfElements(Stack)
   if N = 0 then Return Nil
   Return Stack[N]
EndProc


Procedure Nugget
var FirstChar
   FirstChar = Left(PCLine,1)
   ThisWord = NextWord(PCLine)

   if FirstChar Within('0','9')
      PushStack(Value(ThisWord))

   elseif (FirstChar = '"') or (FirstChar = "'")
      PushStack(ThisWord)

   else
      Run(Hash(ThisWord))

   endif

EndProc


Procedure Interpret
   while PCLine > ''
      Nugget
   endwhile
EndProc


Procedure ExecLeftParen
var OldParenLevel
   OldParenLevel = ParenLevel
   ParenLevel = ParenLevel + 1
   repeat
      Nugget
   until ParenLevel = OldParenLevel
EndProc


Procedure ExecRightParen
   ParenLevel = ParenLevel - 1
EndProc


Procedure StackToParam
var St1 St2
   Interpret
   Loop Stack
      if VarType LoopVal = 'STRING'
         St2 = LoopVal
      endif
      if VarType LoopVal = 'NUMBER'
         St2 = Str(LoopVal)
      endif
      St1 = St1 + St2
   EndLoop
   dispose(Stack)
   Return St1
EndProc


Procedure EatEquals
var St
   if PCLine StartsWith '='
      St = NextWord(PCLine)
   endif
EndProc


Procedure ExecNoBak
   NoBak = True
EndProc


Procedure ReadSetLine (L)
   if InterpretCounter > 1
      PushStack L
   else
      EatEquals
      Interpret
      L = PopStack
   endif
EndProc


Procedure LineLimits
   if StartLine < 1
      StartLine = 1
   endif
   if EndLine > NumberOfElements(FileArray)
      EndLine = NumberOfElements(FileArray)
   endif
   if CurrentLine > EndLine
      CurrentLine = EndLine
   elseif CurrentLine < 0
      CurrentLine = 0
   endif
EndProc


Procedure ExecCurrentLine
   ReadSetLine(Loc CurrentLine)
   LineLimits
EndProc


Procedure ExecStartLine
   ReadSetLine(Loc StartLine)
   LineLimits
EndProc


Procedure ExecEndLine
   ReadSetLine(Loc EndLine)
   LineLimits
EndProc


Procedure ExecFindMode
   ReadSetLine(Loc FindMode)
EndProc


Procedure ExecFileAttribute
   ReadSetLine(Loc FileAttribute)
EndProc


Procedure ExecErrorLevel
   ReadSetLine(Loc ErrorLevel)
EndProc


Procedure ExecDebug
   ReadSetLine(Loc Debug)
EndProc


Procedure ExecA
   ReadSetLine(Loc A)
EndProc


Procedure ExecB
   ReadSetLine(Loc B)
EndProc


Procedure ExecC
   ReadSetLine(Loc C)
EndProc


Procedure ExecD
   ReadSetLine(Loc D)
EndProc


Procedure ExecE
   ReadSetLine(Loc E)
EndProc


Procedure ExecF
   ReadSetLine(Loc F)
EndProc


Procedure ExecG
   ReadSetLine(Loc G)
EndProc


Procedure ExecH
   ReadSetLine(Loc H)
EndProc


Procedure ExecI
   ReadSetLine(Loc I)
EndProc


Procedure ExecJ
   ReadSetLine(Loc J)
EndProc


Procedure ExecK
   ReadSetLine(Loc K)
EndProc


Procedure ExecL
   ReadSetLine(Loc L)
EndProc


Procedure ExecM
   ReadSetLine(Loc M)
EndProc


Procedure ExecN
   ReadSetLine(Loc N)
EndProc


Procedure ExecO
   ReadSetLine(Loc O)
EndProc


Procedure ExecP
   ReadSetLine(Loc P)
EndProc


Procedure ExecQ
   ReadSetLine(Loc Q)
EndProc


Procedure ExecR
   ReadSetLine(Loc R)
EndProc


Procedure ExecS
   ReadSetLine(Loc S)
EndProc


Procedure ExecT
   ReadSetLine(Loc T)
EndProc


Procedure ExecU
   ReadSetLine(Loc U)
EndProc


Procedure ExecV
   ReadSetLine(Loc V)
EndProc


Procedure ExecW
   ReadSetLine(Loc W)
EndProc


Procedure ExecX
   ReadSetLine(Loc X)
EndProc


Procedure ExecY
   ReadSetLine(Loc Y)
EndProc


Procedure ExecZ
   ReadSetLine(Loc Z)
EndProc


Procedure ExecThisLine
   ReadSetLine(Loc FileArray[CurrentLine])
EndProc


Procedure ExecLine
var W Line
   W = InterpretCounter
   Nugget
   InterpretCounter = W
   Line = PopStack
   ReadSetLine(Loc FileArray[Line])
EndProc


Procedure ExecMid
var Pos Count
   Nugget
   Count = PopStack
   Pos = PopStack
   PushStack(Mid(PopStack,Pos,Count))
EndProc


Procedure AddLine (St)
   CurrentLine = CurrentLine + 1
   ArrayInsert(FileArray,CurrentLine,1)
   FileArray[CurrentLine] = St
EndProc


Procedure ExecAddLine
   AddLine(StackToParam)
EndProc


Procedure ExecWholeFile
   StartLine = 1
   EndLine = NumberOfElements(FileArray)
   LineLimits
EndProc


Procedure ExecReadFile
var Name A Size
   if PCLine > ''
      Nugget
      Name = PopStack
   else
      if NameOfFile = '' then Name = ParamStr(3)
   endif
   if Name = ''
      Error('File Name not Specified!',PC)
   endif
   Name = CleanFileName(Name)
   if ExistFile(Name)
      ReadTextFile(Name,A)
      if NumberOfElements(FileArray) = 0

         ;- Read First File

         FileArray = A
         ExecWholeFile
         CurrentLine = EndLine
      else

         ;- insert a file into buffer

         Size = NumberOfElements(A)
         ArrayInsert(FileArray,CurrentLine + 1,Size)
         Loop A
            FileArray[CurrentLine + LoopIndex] = LoopVal
         EndLoop
         StartLine = CurrentLine + 1
         CurrentLine = CurrentLine + Size
         EndLine = CurrentLine
      endif
   else
      Error('File ' + Name + ' not Found!',PC)
   endif
   if NameOfFile = ''

      ;- Save first file name and attributes

      NameOfFile = Name
      FileAttribute = FileAttr(Name)
   endif
EndProc


Procedure ExecWriteFile
var Name BackName Tmp
   Loop FileArray
      if (LoopVal > '') or (FileArray[LoopIndex + 1] > '')
         AppendArray(Tmp,LoopVal)
      endif
   EndLoop
   FileArray = Tmp
   dispose(Tmp)
   Trim(FileArray)
   if PCLine > ''
      Nugget
      Name = PopStack
   else
      Name = NameOfFile
   endif

   if NoBak
      DelFile(Name)
   else
      BackName = ForceExtension(Name,'BAK')
      DelFile(BackName)
      FileAttr(Name) = 0
      FileRename(Name,BackName)
   endif

   WriteTextFile(Name,FileArray)
   if (FileAttribute and 7 > 0) and (Name = NameOfFile)
      FileAttr(NameOfFile) = FileAttribute
   endif
   dispose FileArray
   NameOfFile = ''
EndProc


Procedure ExecDeleteFile
   Interpret
   DelFile(PopStack)
EndProc


Procedure ExecRenameFile
var Old New
   Interpret
   New = PopStack
   Old = PopStack
   FileRename(Old,New)
EndProc


Procedure ExecChDir
   Interpret
   ChDir(PopStack)
EndProc


Procedure ExecMkDir
   Interpret
   MkDir(PopStack)
EndProc


Procedure ExecRmDir
   Interpret
   RmDir(PopStack)
EndProc


Procedure ExecCurrentDirectory
   PushStack(CurrentDirectory)
EndProc


Procedure ExecSubSt
var St Old New
   Interpret
   New = PopStack
   Old = PopStack
   Loop StartLine EndLine FileArray
      Substitute LoopVal Old New
   EndLoop
EndProc


Procedure ExecReplace
var St Old New
   Interpret
   New = PopStack
   Old = PopStack
   Substitute FileArray[CurrentLine] Old New
EndProc


Procedure ExecLength
   Nugget
   PushStack(Length(PopStack))
EndProc


Procedure ExecDelLine
   Interpret
   if NumberOfElements(Stack) = 1
      CurrentLine = PopStack
   endif
   delete(FileArray,CurrentLine,1)
   LineLimits
EndProc


Procedure ExecDelBlock
   Interpret
   if NumberOfElements(Stack) = 2
      EndLine = PopStack
      StartLine = PopStack
   endif
   delete(FileArray,StartLine,EndLine - StartLine + 1)
   ExecWholeFile
EndProc


Procedure ExecExit
   ExitCode = ErrorLevel
   ExitMenu
EndProc


Procedure ExecPlus
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A + B)
EndProc


Procedure ExecMinus
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A - B)
EndProc


Procedure ExecTimes
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A * B)
EndProc


Procedure ExecDiv
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A / B)
EndProc


Procedure ExecEqual
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A = B)
EndProc


Procedure ExecNotEqual
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A <> B)
EndProc


Procedure ExecGreater
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A > B)
EndProc


Procedure ExecLess
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A < B)
EndProc


Procedure ExecGreaterEqual
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A >= B)
EndProc


Procedure ExecLessEqual
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A <= B)
EndProc


Procedure ExecAnd
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A and B)
EndProc


Procedure ExecOr
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A or B)
EndProc


Procedure ExecXor
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A Xor B)
EndProc


Procedure ExecNot
   Nugget
   PushStack(not PopStack)
EndProc


Procedure ExecStartsWith
var A B
   Nugget
   B = PopStack
   A = PopStack
   PushStack(A StartsWith B)
EndProc


Procedure ExecUpperCase
   Nugget
   PushStack(UpperCase(PopStack))
EndProc


Procedure ExecIf
EndProc


Procedure ExecGoTo
   PC = Value(PCLine) - 1
   PCLine = ''
EndProc


Procedure ExecIfNotGoTo
   if PopStack
      PCLine = ''
   else
      ExecGoto
   endif
EndProc


Procedure ExecExistFile
   Nugget
   PushStack(ExistFile(PopStack))
EndProc


Procedure ExecExistDir
   Nugget
   PushStack(ExistDir(PopStack))
EndProc


Procedure ExecReadEnv
   Nugget
   PushStack(ReadEnv(PopStack))
EndProc


Procedure ExecWrite
   Interpret
   Loop Stack
      Write LoopVal
   EndLoop
   dispose(Stack)
EndProc


Procedure ExecWriteln
   ExecWrite
   Writeln
EndProc


Procedure ExecLastLine
   PushStack(NumberOfElements(FileArray))
EndProc


Procedure FindLine (St)
   if FindMode = 'C'
      Loop StartLine EndLine FileArray
         if LoopVal contains St
            WhereFound = LoopIndex
            Return True
         endif
      EndLoop

   elseif FindMode = 'S'
      Loop StartLine EndLine FileArray
         if LoopVal StartsWith St
            WhereFound = LoopIndex
            Return True
         endif
      EndLoop

   elseif FindMode = 'M'
      Loop StartLine EndLine FileArray
         if LoopVal = St
            WhereFound = LoopIndex
            Return True
         endif
      EndLoop

   endif
   Return False
EndProc


Procedure ExecFind
var F
   Nugget
   F = FindLine(PopStack)
   PushStack(F)
   if F then CurrentLine = WhereFound
EndProc


Procedure ExecFindRange
var St1 St2
   Nugget
   St2 = PopStack
   St1 = PopStack
   if FindLine(St1)
      CurrentLine = WhereFound
      StartLine = WhereFound + 1
      if FindLine(St2)
         EndLine = WhereFound - 1
      else
         EndLine = NumberOfElements(FileArray)
      endif
      PushStack(True)
   else
      PushStack(False)
   endif
EndProc


Procedure ExecDelSection
Var Section S E
   Nugget
   Section = PopStack
   Trim(Section)
   S = PosInListPartial('SECTION: ' + Section,FileArray)
   if S > 0
      E = PosInListPartial('END SECTION: ' + Section,FileArray)
      if E > 0
         delete(FileArray,S,E - S + 1)
         ExecWholeFile
      endif
   endif
EndProc


Procedure ExecCPU
   PushStack(CPUClass)
EndProc


Procedure ExecMathChip
   PushStack(McpClass > 0)
EndProc


Procedure ExecUserName
   if VinesLoaded
      PushStack(VinUserName)
   else
      PushStack(NovLoginName)
   endif
EndProc


Procedure ExecPos
var Key St
   Nugget
   St = PopStack
   Key = PopStack
   PushStack(Pos(Key,St))
EndProc


Procedure ExecContains
var Key St
   Nugget
   St = PopStack
   Key = PopStack
   PushStack(St Contains Key)
EndProc


Procedure ExecExecute
   Swapping On
   Execute StackToParam
EndProc


Procedure ExecDelChar
var Start Count St
   Nugget
   Count = PopStack
   Start = PopStack
   St = PopStack
   delete(St,Start,Count)
   PushStack(St)
EndProc


Procedure ExecInsChar
Var Pos Ins St
   Nugget
   Pos = PopStack
   St = PopStack
   Ins = PopStack
   insert(Ins,St,Pos)
   PushStack(St)
EndProc


Procedure ReadGroupList
   if GroupsRead then Return
   if NovConnection > 0
      NovReadGroups(NovLoginName,GroupList)
      SortArray(GroupList)
   endif
   GroupsRead
EndProc


Procedure ExecInGroup
var Group
   ReadGroupList
   Nugget
   Group = PopStack
   PushStack(PosInSortedList(Group,GroupList) > 0)
EndProc


Procedure ReadSecurityEqual
   if SecurityRead then Return
   if NovConnection > 0
      NovReadSecurityEquals(NovLoginName,SecurityList)
      SortArray(SecurityList)
   endif
   SecurityRead
EndProc


Procedure ExecSecurityEqual
var Security
   ReadSecurityEqual
   Nugget
   Security = PopStack
   PushStack(PosInSortedList(Security,SecurityList) > 0)
EndProc


Procedure ExecStation
   PushStack(NovStationAddress)
EndProc


Procedure ExecDisplay
var Disp
   Disp = DisplayType

   if Disp = 0
      PushStack 'HERC'

   elseif Disp = 1
      PushStack 'CGA'

   elseif Disp = 3
      PushStack 'EGA'

   elseif Disp = 4
      PushStack 'VGA'

   else
      PushStack ''

   endif
EndProc


Procedure ExecDayOfWeek
var D
   D = DayOfWeek

   if D = 0
      PushStack 'SUN'

   elseif D = 1
      PushStack 'MON'

   elseif D = 2
      PushStack 'TUE'

   elseif D = 3
      PushStack 'WED'

   elseif D = 4
      PushStack 'THU'

   elseif D = 5
      PushStack 'FRI'

   elseif D = 6
      PushStack 'SAT'

   endif
EndProc


Procedure ExecMonth
var D
   D = Month

   if D = 1
      PushStack 'JAN'

   elseif D = 2
      PushStack 'FEB'

   elseif D = 3
      PushStack 'MAR'

   elseif D = 4
      PushStack 'APR'

   elseif D = 5
      PushStack 'MAY'

   elseif D = 6
      PushStack 'JUN'

   elseif D = 7
      PushStack 'JUL'

   elseif D = 8
      PushStack 'AUG'

   elseif D = 9
      PushStack 'SEP'

   elseif D = 10
      PushStack 'OCT'

   elseif D = 11
      PushStack 'NOV'

   elseif D = 12
      PushStack 'DEC'

   endif
EndProc


Procedure ExecReBoot
   ColdBoot
EndProc


Procedure GetTimeOf (St)
   if ExistFile(St)
      Return FileTime(St)
   else
      Return TimeOf(St)
   endif
EndProc


Procedure ExecTimeOf
var St
   Nugget
   PushStack(GetTimeOf(PopStack))
EndProc


Procedure ExecNow
   PushStack(Now)
EndProc


Procedure ExecIsOlderThan
var St1 St2
   Nugget
   St2 = PopStack
   St1 = PopStack
   PushStack(GetTimeOf(St1) < GetTimeOf(St2))
EndProc


Procedure ExecParam
Var P
   Nugget
   P = PopStack
   PushStack(ParamStr(P))
EndProc


Procedure ExecNameOfFile
   PushStack(NameOfFile)
EndProc


Procedure ExecMissingParam
   Error('Required Parameter Missing!',PC)
EndProc


Procedure ExecTimer
   PushStack(Timer)
EndProc


Procedure ExecTrue
   PushStack(True)
EndProc


Procedure ExecFalse
   PushStack(False)
EndProc


Procedure ExecDosVersion
   PushStack(DosVersion * 100 + MinorDosVersion)
EndProc


Procedure ExecFileLog
var Name St
   Interpret
   St = PopStack
   Name = PopStack
   FileLog(Name,St)
EndProc


Procedure ExecLeftOfEqual
   Nugget
   PushStack(LeftOfEqual(PopStack))
EndProc


Procedure ExecRightOfEqual
   Nugget
   PushStack(RightOfEqual(PopStack))
EndProc


Procedure ExecLeft
var St Count
   Nugget
   Count = PopStack
   St = PopStack
   PushStack(Left(St,Count))
EndProc


Procedure ExecRight
var St Count
   Nugget
   Count = PopStack
   St = PopStack
   PushStack(Right(St,Count))
EndProc


Procedure ExecValue
   Nugget
   PushStack(Value(PopStack))
EndProc


Procedure ExecStr
   Nugget
   PushStack(Str(PopStack))
EndProc


Procedure ExecOrd
   Nugget
   PushStack(Ord(Left(PopStack,1)))
EndProc


Procedure ExecChar
   Nugget
   PushStack(Char(PopStack))
EndProc


Procedure ExecSetEnv
   Interpret
   SetEnv(PopStack)
EndProc


Procedure ExecConsoleOperator
   PushStack(NovConsoleOperator)
EndProc


Procedure ExecServer
   PushStack(NovDefaultServer)
EndProc


Procedure ExecFullName
   PushStack(NovFullName(NovMyLoginName))
EndProc


Procedure ExecVlmLoaded
   PushStack(VlmLoaded)
EndProc


Procedure ExecVinesLoaded
   PushStack(VinesLoaded)
EndProc


Procedure ExecSupervisor
   PushStack(NovBinderyAccess >= 3)
EndProc


Procedure ExecLoggedIn
   PushStack(NovBinderyAccess >= 1)
EndProc


Procedure SetupLibWords
   Hash ('')                  = Loc ExecMissingParam
   Hash ('(')                 = Loc ExecLeftParen
   Hash (')')                 = Loc ExecRightParen
   Hash ('*')                 = Loc ExecTimes
   Hash ('+')                 = Loc ExecPlus
   Hash ('-')                 = Loc ExecMinus
   Hash ('/')                 = Loc ExecDiv
   Hash ('<')                 = Loc ExecLess
   Hash ('<=')                = Loc ExecLessEqual
   Hash ('<>')                = Loc ExecNotEqual
   Hash ('=')                 = Loc ExecEqual
   Hash ('>')                 = Loc ExecGreater
   Hash ('>=')                = Loc ExecGreaterEqual
   Hash ('ADDLINE')           = Loc ExecAddLine
   Hash ('AND')               = Loc ExecAnd
   Hash ('CHAR')              = Loc ExecChar
   Hash ('CHDIR')             = Loc ExecChDir
   Hash ('CONSOLEOPERATOR')   = Loc ExecConsoleOperator
   Hash ('CONTAINS')          = Loc ExecContains
   Hash ('CPU')               = Loc ExecCpu
   Hash ('CURRENTDIRECTORY')  = Loc ExecCurrentDirectory
   Hash ('CURRENTLINE')       = Loc ExecCurrentLine
   Hash ('DAYOFWEEK')         = Loc ExecDayOfWeek
   Hash ('DEBUG')             = Loc ExecDebug
   Hash ('DELBLOCK')          = Loc ExecDelBlock
   Hash ('DELCHAR')           = Loc ExecDelChar
   Hash ('DELETEFILE')        = Loc ExecDeleteFile
   Hash ('DELLINE')           = Loc ExecDelLine
   Hash ('DELSECTION')        = Loc ExecDelSection
   Hash ('DISPLAY')           = Loc ExecDisplay
   Hash ('DOSVERSION')        = Loc ExecDosVersion
   Hash ('ELSEIF')            = Loc ExecIf
   Hash ('ENDLINE')           = Loc ExecEndLine
   Hash ('ERRORLEVEL')        = Loc ExecErrorLevel
   Hash ('EXECUTE')           = Loc ExecExecute
   Hash ('EXISTDIR')          = Loc ExecExistDir
   Hash ('EXISTFILE')         = Loc ExecExistFile
   Hash ('EXIT')              = Loc ExecExit
   Hash ('FALSE')             = Loc ExecFalse
   Hash ('FILEATTRIBUTE')     = Loc ExecFileAttribute
   Hash ('FILELOG')           = Loc ExecFileLog
   Hash ('FIND')              = Loc ExecFind
   Hash ('FINDMODE')          = Loc ExecFindMode
   Hash ('FINDRANGE')         = Loc ExecFindRange
   Hash ('FULLNAME')          = Loc ExecFullName
   Hash ('GOTO')              = Loc ExecGoto
   Hash ('IF')                = Loc ExecIf
   Hash ('IFNOTGOTO')         = Loc ExecIfNotGoto
   Hash ('INGROUP')           = Loc ExecInGroup
   Hash ('INSCHAR')           = Loc ExecInsChar
   Hash ('ISOLDERTHAN')       = Loc ExecIsOlderThan
   Hash ('LASTLINE')          = Loc ExecLastLine
   Hash ('LEFT')              = Loc ExecLeft
   Hash ('LEFTOFEQUAL')       = Loc ExecLeftOfEqual
   Hash ('LENGTH')            = Loc ExecLength
   Hash ('LINE')              = Loc ExecLine
   Hash ('LOGGEDIN')          = Loc ExecLoggedIn
   Hash ('MATHCHIP')          = Loc ExecMathChip
   Hash ('MID')               = Loc ExecMid
   Hash ('MKDIR')             = Loc ExecMkDir
   Hash ('MONTH')             = Loc ExecMonth
   Hash ('NAMEOFFILE')        = Loc ExecNameOfFile
   Hash ('NOBAK')             = Loc ExecNoBak
   Hash ('NOT')               = Loc ExecNot
   Hash ('NOW')               = Loc ExecNow
   Hash ('OR')                = Loc ExecOr
   Hash ('ORD')               = Loc ExecOrd
   Hash ('PARAM')             = Loc ExecParam
   Hash ('POS')               = Loc ExecPos
   Hash ('READENV')           = Loc ExecReadEnv
   Hash ('READFILE')          = Loc ExecReadFile
   Hash ('REBOOT')            = Loc ExecReBoot
   Hash ('RENAMEFILE')        = Loc ExecRenameFile
   Hash ('REPLACE')           = Loc ExecReplace
   Hash ('RIGHT')             = Loc ExecRight
   Hash ('RIGHTOFEQUAL')      = Loc ExecRightOfEqual
   Hash ('RMDIR')             = Loc ExecRmDir
   Hash ('SECURITYEQUAL')     = Loc ExecSecurityEqual
   Hash ('SERVER')            = Loc ExecServer
   Hash ('SETENV')            = Loc ExecSetEnv
   Hash ('STARTLINE')         = Loc ExecStartLine
   Hash ('STARTSWITH')        = Loc ExecStartsWith
   Hash ('STATION')           = Loc ExecStation
   Hash ('STR')               = Loc ExecStr
   Hash ('SUBST')             = Loc ExecSubSt
   Hash ('SUPERVISOR')        = Loc ExecSupervisor
   Hash ('THISLINE')          = Loc ExecThisLine
   Hash ('TIMEOF')            = Loc ExecTimeOf
   Hash ('TIMER')             = Loc ExecTimer
   Hash ('TRUE')              = Loc ExecTrue
   Hash ('UPPERCASE')         = Loc ExecUpperCase
   Hash ('USERNAME')          = Loc ExecUserName
   Hash ('VALUE')             = Loc ExecValue
   Hash ('VINESLOADED')       = Loc ExecVinesLoaded
   Hash ('VLMLOADED')         = Loc ExecVlmLoaded
   Hash ('WHILE')             = Loc ExecIf
   Hash ('WHOLEFILE')         = Loc ExecWholeFile
   Hash ('WRITE')             = Loc ExecWrite
   Hash ('WRITEFILE')         = Loc ExecWriteFile
   Hash ('WRITELN')           = Loc ExecWriteln
   Hash ('XOR')               = Loc ExecXor
   Hash ('A')                 = Loc ExecA
   Hash ('B')                 = Loc ExecB
   Hash ('C')                 = Loc ExecC
   Hash ('D')                 = Loc ExecD
   Hash ('E')                 = Loc ExecE
   Hash ('F')                 = Loc ExecF
   Hash ('G')                 = Loc ExecG
   Hash ('H')                 = Loc ExecH
   Hash ('I')                 = Loc ExecI
   Hash ('J')                 = Loc ExecJ
   Hash ('K')                 = Loc ExecK
   Hash ('L')                 = Loc ExecL
   Hash ('M')                 = Loc ExecM
   Hash ('N')                 = Loc ExecN
   Hash ('O')                 = Loc ExecO
   Hash ('P')                 = Loc ExecP
   Hash ('Q')                 = Loc ExecQ
   Hash ('R')                 = Loc ExecR
   Hash ('S')                 = Loc ExecS
   Hash ('T')                 = Loc ExecT
   Hash ('U')                 = Loc ExecU
   Hash ('V')                 = Loc ExecV
   Hash ('W')                 = Loc ExecW
   Hash ('X')                 = Loc ExecX
   Hash ('Y')                 = Loc ExecY
   Hash ('Z')                 = Loc ExecZ
EndProc


Procedure Beg
var Jessica
   BoxHeader ' * Shameless Beg Screen * '
   DrawBox 10 8 61 7
   Writeln
   WriteCenter '* BatZap Evaluation Copy *'
   Writeln
   WriteCenter 'Please remember to register this software.'
   Writeln
   if Timer and 1 = 0
      Jessica = Now - TimeOf('1-17-80') / SecondsInDay / 365 + 2
      WriteCenter 'I have a ' Jessica ' year old daughter who wants to go shopping.'
   else
      WriteCenter "I'd sure hate to have to find a real job."
   endif
   Wait 600
   EraseTopWindow
   ClearKbdBuffer
EndProc


Procedure Help
var Help HelpFile
   HelpFile = ExistOnPath 'BATZAP.HLP'
   if HelpFile = ''
      Writeln
      Writeln 'BatZap * Copyright 1994 by Marc Perkel'

      Include 'ADDRESS.INC'

      Writeln 'Missing file ' HelpFile
   else
      BoxHeader ' Viewing ' + HelpFile + ' '
      DrawBox 1 1 ScreenWidth ScreenHeight
      ViewTextFile(HelpFile)
   endif
   ExitMenu
EndProc


Procedure PBL (Line)
   while Script[Line] = ''
      Line = Line + 1
   endwhile
   Return Str(Line)
EndProc


Procedure BBL (Line)
   while Script[Line] = ''
      Line = Line - 1
   endwhile
   Return Line
EndProc


Procedure Setup
var P L Name Flag
  ;Beg
   Name = ParamStr(2)
   if Name = '' then Help
   StandardIO
   Name = CleanFileName(ForceExtension(Name,'BZ'))
   ReadTextFile(Name,Script)
   Orig = Script
   AppendArray(Script,'EXIT')
   FindMode = 'C'
   ParenLevel = 0
   SetupLibWords
   UpperCaseCompare
   NilProgram = Loc UnknownCommand
   Loop Script
      trim(LoopVal)
      if LoopVal StartsWith ';'
         LoopVal = ''

      elseif LoopVal StartsWith 'IF '
         PushStack(LoopIndex)
         PushStack(-1)

      elseif LoopVal = 'ENDIF'
         LoopVal = ''

         repeat
            Flag = PopStack
            P = PopStack
            L = PBL(LoopIndex + 1)
            if Flag = -1
               Script[P] = Script[P] + ' IfNotGoto ' + L
            elseif Flag within (-3,-2)
               P = BBL(P-1)
               Script[P] = Script[P] + ' Goto ' + L
               Trim(Script[P])
            else
               MisMatch(LoopIndex)
            endif
         until StackTop <> -3

      elseif LoopVal StartsWith 'ELSEIF '
         Flag = PopStack
         P = PopStack

         if Flag = -1
            Script[P] = Script[P] + ' IfNotGoto ' + PBL(LoopIndex)
         else
            MisMatch(LoopIndex)
         endif

         ;- else

         PushStack(LoopIndex)
         PushStack(-3)

         ;- if

         PushStack(LoopIndex)
         PushStack(-1)

      elseif LoopVal = 'ELSE'
         LoopVal = ''
         Flag = PopStack
         P = PopStack
         if Flag = -1
            Script[P] = Script[P] + ' IfNotGoto ' + PBL(LoopIndex + 1)
         else
            MisMatch(LoopIndex)
         endif
         PushStack(LoopIndex)
         PushStack(-2)

      elseif LoopVal StartsWith 'WHILE '
         PushStack(LoopIndex)
         PushStack(-4)

      elseif LoopVal = 'ENDWHILE'
         LoopVal = ''
         Flag = PopStack
         P = PopStack
         if Flag = -4
            L = BBL(LoopIndex - 1)
            Script[L] = Script[L] + ' Goto ' + PBL(P)
            Script[P] = Script[P] + ' IfNotGoto ' + PBL(LoopIndex + 1)
            trim(Script[P])
         else
            MisMatch(LoopIndex)
         endif

      endif

   EndLoop

   ;-- if you forgot an Endif then the stack contains values.

   if NumberOfElements Stack <> 0
      Flag = PopStack
      MisMatch(PopStack)
   endif

   ;- for debugging
{
   Loop Script
      Writeln LoopIndex ' - ' LoopVal
   EndLoop
   Writeln
   ExitMenu}

EndProc


Procedure MisMatch (Line)
   Error ('MisMatched Conditionals!',Line)
EndProc


Procedure Main
   BoxBorderColor Green Blue
   BoxInsideColor White Blue
   BoxHeaderColor Yellow Mag
   Setup
   repeat
      PC = PC + 1
      PCLine = Script[PC]
      if PCLine > ''
         if Debug then Writeln PC ' - ' PCLine
         InterpretCounter = 0
         Interpret
         if NumberOfElements(Stack) > 0
            Error('Too Many Parameters!',PC)
         endif
      endif
   forever
EndProc