ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿
 ³         COMMO  Phone Directory         ³
 ÀÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÙ
   SYSTEM NAME              LAST CALL             PHONE NUMBER                     PASSWORD     MACRO   PARAMETERS
ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿           ÚÄÄÄÄÄÄ¿             ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ¿              ÚÄÄÄÄÄÄÄÄÄÄÄÄ¿ ÚÄÄÄ¿ ÚÄÄÄÄÄÄÄÄÄÄÄ¿
NetConnection               09/07/91             {%prfx2 882-5575 }              {            } {net} {38400,8n1,3}
DirectoryAssist             09/07/91             {%prfx2 1-707-538-8710}         {            } {   } {38400,8n1,3}
SemWare                     09/07/91             {%prfx2 1-404-641-8968}         {            } {   } {38400,8n1,3}
WatchWord                   09/07/91             {%prfx2 247-1382 }              {            } {wat} {38400,8n1,3}
DownEast Roots              00/00/00             {%prfx1 1-603-964-7912}         {            } {   } {2400,8n1,3}
MAS-BBS                     00/00/00             {%prfx2 1 718 444 4555}         {            } {   } {38400,8n1,3}
Motherboard                 00/00/00             {%prfx2 1 707 778 8841}         {            } {   } {38400,8n1,3}
Palladin                    00/00/00             {%prfx2 1 415 485 1736}         {            } {   } {38400,8n1,3}
Babble Undrgrnd             00/00/00             {%prfx2 1 707 575 0636}         {            } {   } {38400,8n1,3}
The Assembler               00/00/00             {%prfx2 1 503 343 6383}         {            } {   } {38400,8n1,3}
Northern Lights             00/00/00             {%prfx2 1 207 766 5788}         {            } {   } {38400,8n1,3}

         %prfx# indicates MODEM PARAMETERS for my HST

         passwords and link parameters are off screen to the right

         NOTE: called macros load individual BBS variables
 ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
 Login  PCBoard BBS             (put "pcb" in Dialing Directory macro field)
 ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
 {:pcb} {pushstack} {setlook 60,hng,6,n|}
    {golook yqn,want graphics}
    {golook yqn,graphics (Enter)=no}
    {golook ntr,Language # to use}
    {golook nam,first name?}
    {golook yes,correct? (}
    {golook ntr,More?}
    {golook noo,(H)elp, More?}
    {golook pas,will echo)?}
    {golook ntr,continue?}
    {golook noo,'Last Read'}
    {golook pc1,Main Board - Your Com}
    {lookfor Main Board Command?} {send n s u|} {popstack} {}
 {:pc1} {send n s u|} {popstack} {}
 ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ




 ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
 Login  WildCat! BBS            (put "cat" in Dialing Directory macro field)
 ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
 {:cat} {pushstack} {SETL 60,hng,6,|}
    {golook ntr,Last Name}
    {golook ntr,[C]ontinue}
    {golook ntr,[ENTER] for a}
    {golook ntr,[ENTER] to contin}
    {golook npa,First Name}
    {golook ntr,[ENTER] to Quit}
    {golook noo,bulletin menu [Y/n]?}
    {golook noo,view it [Y/n]?}
    {golook ca1,XXX-XXX-XXXX}
    {golook ca2,MM-DD-YY}
    {golook ntr,Correct [Y/n] ?}
    {lookfor MAIN MENU:} {popstack} {}
 {:ca1} {send 317-839-2983|} {return}
 {:ca2} {send 03/26/41|} {return}
 ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ



 ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
 Shared CALLED functions
 ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
 {:yqn}  {send y q ns|} {return}
 {:yes}  {send y|} {return}
 {:ntr}  {send |} {return}
 {:noo}  {send n|} {return}
 {:nam}  {send Pat Shanahan|} {return}
 {:npa}  {send Pat Shanahan|~%_passowrd|} {return}
 {:pas}  {send %_password|} {return}
 {:esk}  {send ^[} {return}
 {:hng}  {send hangup y} {}
 {:mnu}  {popstack} {}
 ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ








 ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
 The following set variables to allow me to use a generic script for mail.  The
 different looks/language for each BBS can be adjusted this way.  I run mail
 to/from IBM-NET (pcboard), COMPUTERS 2000 (pcboard), and WATCHWORD (wildcat)
 automatically with these parameters.
 ÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ
 {:icc}  {setvar bbsid,icc} {setvar 2mail,open 21} {setvar lname,icc}
    {setvar lk_str1,) MarkMail Command?} {setvar dmail,dg} {setvar smail,u}
    {setvar quit_str,g} {goto pcb}
 {:net}  {setvar bbsid,net} {setvar 2mail,open 14} {setvar lname,ibm-net}
    {setvar lk_str1,Qmail Command?} {setvar dmail,dg} {setvar smail,u}
    {setvar quit_str,g} {goto pcb}
 {:wat}  {setvar bbsid,wtch} {setvar 2mail,d|~~~~~~3} {setvar lname,watchw}
    {setvar lk_str1,TOMCAT MENU [C} {setvar dmail,d} {setvar smail,u}
    {setvar quit_str,g} {goto cat}
 ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ






 ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ
 DO MAIL RUN                                     ;rev 09-07-91 5:22p
{:domail}  {setlook 90,hng}
    {send %2mail%|}
    {lookfor %lk_str1%}
    {ifexist %uldir%\%lname%.rep,smail,}         ;have replies?, upload them

{:dmail}  {send %dmail%|}                        ;req dload & quit
    {setlook 300,hng}
    {golook no_mail,Sorry,}                      ;have mail? quit if not
    {golook want_mail,wish to receive}           ;yes, want it        QMAIL DOOR
{:start_dl}  {lookfor ^xB00}                     ;initiate zmodem dload

DAVE -NOTE: 'exec-da' and '%_port' and '%dldir%' - I most generally put the '%'
        delimiter at each end of a variable.  That way I don't have to remember
        what chars are acceptable as delimiters.  EXEC-DA tells COMMO to execute
        DSZ (full path and name required) without invoking COMMAND.COM [the -D
        does this] and to sound the ALARM when finished [the A on -DA].

    {exec-da e:\commo\DSZ.exe port %_port ha on est 0 19200 d rz -rrmS %dldir%\}
    {lookfor was successful}
    {send %quit_str%|}

    {ifexist %dldir%\%lname%.qwk,,clr_vars}      ;have .qwk?, rename it or quit
    {ropen e:\commo\num.log,inc_num}             ;get seq number
    {read number}                                ;one line file, auto closes
{:inc_num}  {increment number}                   ;increment number (no dups)
    {exec-N ren %dldir\%lname%.qwk %dldir%\%bbsid%%number%.qwk}

    {wopen e:\commo\num.log}                     ;write new number back
    {write %number%}                             ; to file to maintain sequence
    {wclose}

{:clr_vars}  {setvar number,}                    ;clear variable space
    {setvar temp,}
    {setvar bbsid,}
    {setvar lname,}
    {setvar lk_str1,}
    {setvar 2mail,}
    {setvar smail,}
    {setvar dmail,}
    {setvar quit_str,}
    {setvar file,}
    {return}                                     ;return to NOWHERE, quits!

{:smail}  {send %smail%|}                        ;send replies
    {lookfor ^xB01}
    {exec-da e:\commo\DSZ.exe port %_port ha on est 0 19200 D z pL1024 sz -rrmZkS %uldir%\%lname%.rep}
    {iferr 1,,good_ul}                           ;check environment variable for
    {goto dmail}                                 ; for uload success
{:good_ul}  {exec del %uldir%\%lname%.rep}       ;delete upload packet if uload
    {goto dmail}                                 ; is successful

{:want_mail}  {send y|}
    {goto start_dl}

{:no_mail}  {send %quit_str%|}                   ;quit, no mail.
    {goto clr_vars}


I added a few comments to help explain - if you start from the top, screens
are arranged to always begin at TOS.


Pat Shanahan {waiting since 09-01-91}, Plainfield, IN
 ÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ