SCRIPT 3 Late Nite Auto-pass
ECHO OFF
:GET_PASS
CLEAR
NOTE ""
NOTE "      Perform Unattended Late Nite Auto-pass"
NOTE ""
Note "Perform Auto-pass 1 or 2?  (Press <ESC> to quit)"
GETKEY 0
IF STRING 0 IS "^["
  GOTO END
ENDIF
IF STRING 0 IS "1"
  GOTO GET_TIME
ENDIF
IF STRING 0 IS "2"
  GOTO GET_TIME
ENDIF
GOTO GET_PASS
:GET_TIME
NOTE ""
Note "Enter Time To Begin Auto-pass %0 (24-hour format HH:MM)"
NOTE "HH:MM       (press <RETURN> for default time shown)"
SETSTRING 1 "02:#N"
GETSTRING 1
IF STRING 1 HAS ":"
ELSE
  BEEP
  BEEP
  NOTE "You Forgot the Colon (:)!"
  GOTO GET_TIME
ENDIF
NOTE ""
NOTE "Do you wish to continue Auto-pass %0 if is determined that "
NOTE "log on has occured during Prime Time? (Y/N)?"
GETSTRING 2
IF STRING 2 IS "Y"
  SETSTRING 2 "y"
ENDIF
CLEAR
NOTE ""
NOTE "Unattended Auto Passes should not be left unattended for   "
NOTE "more than 1/2 hour past their expected completion, UNLESS  "
NOTE "you are confident of a trouble free connection between your"
NOTE "modem and GEnie.  Interference from occurrences such as    "
NOTE "line noise can produce unexpected results.                 "
NOTE ""
NOTE ""
NOTE "         Waiting Until %1 to Begin Auto-pass %0"
NOTE "                (press any key to abort)"
WAITUNTIL %1
IF SUCCESS
  LOG ON
  IF STRING 2 IS "y"
  ELSE
  SENDLINE "TIMEP"
  WAITFOR "Time:"
  IF CURRENTLINEHAS "P Time:"
    HANGUP
    BEEP
    CLEAR
    NOTE ""
    NOTE ""
    NOTE "        Unattended Auto-pass was aborted because it was"
    NOTE "        detected that log on occured during Prime Time."
    NOTE ""
    NOTE "               Press any key to continue..."
    WAITFORKEYPRESS
    GOTO END
  ENDIF
  WAITFORPROMPT
  ENDIF
  PERFORM %0
ELSE
  BEEP
  NOTE "SCRIPT ABORTED!"
  PAUSE 3
ENDIF
:END
ENDSCRIPT