Exploring the EGA, Part 1
          (PC Magazine August 1986 by Charles Petzold)

     IBM's introduction of the Enhanced Graphics Adapter (EGA) and
Enhanced Color Display (ECD) in the fall of 1984 came with little
warning, and as a result the rest of the industry has been slow to
catch up with software support and compatible hardware.  Now the EGA
has established itself as the high-resolution color graphics standard
for all but specialized applications.
     Whether you're a veteran owner or recent purchaser of an EGA,
you may have been disappointed that the documentation IBM supplies
with the EGA board covers only installation.  Most manufacturers of
EGA compatibles don't do much better.  Most EGAs do not come with
demonstration programs.  Although the improved resolution of the EGA
is obvious to the eye, it's certainly not clear what other magic is
packed into the board.
     With only a few exceptions, the programs presented here use the
BIOS Interrupt 10h video routines to communicate with the EGA.  The
techniques demonstrated in this article can be incorporated into
programs written in high-level languages, however, since many of them
(such as Turbo Pascal) also support BIOS calls.  (BASIC, of course,
is the most notable exception.)
     To go beyond whats in this article and Part II, you'll have to
get a copy of the EGA Technical Reference.  This is available only as
an update to the two-volume IBM Options and Adapters Technical
Reference (IBM part number 6322509, $125).  An article on the EGA in
the April 1985 issue of PC Tech Journal (Volume 3 Number 4) also has
a good description of the BIOS calls.


Creating the Utilities

    The short programs presented here are written in assembly language.
For most of them, however, you do not need to use the IBM or Microsoft
Macro Assembler.  Instead, the programs are presented in a script
format that allows you to create the executable .COM files using DEBUG
(2.0 or later).
    First type each listing into an ASCII file with the extension .SCR.
You can create the ASCII file with any word processor (or DOS's EDLIN)
that can create ASCII files.  (Or, since this text file was created in
ASCII, you can use a word processor to "block" the programs and "move"
or "write" them out to a file with the filename specified including the
extension .SCR.  For example, the program for EGAMODE.COM below could
be blocked and copied out to the file EGAMODE.SCR.)
     You'll notice that each program listing has at least one blank
line near the bottom.  The blank line is very important, so make sure
your .SCR file has a blank line in the same place.  You do not have to
type in the semicolons or anything to the right of the semicolons;
these are comments and labels to help you understand what is going on
in the program.
     Second, use DEBUG to create the executable .COM file with the
command:

DEBUG <filename.SCR

where filename is the name of the .SCR file.  If you accidentally omit
the left angle bracket, enter Q to exit DEBUG and try again.  When
DEBUG creates the .COM file from the .SCR file, watch for error
messages.  An error message from DEBUG indicates a mistake in your
typing (or mine).
     As an alternative, you can skip the creation of the .SCR file by
just entering:

DEBUG

and typing in the lines directly.
     If you have a Macro Assembler and some experience in assembly
language programming, you may want to convert these .SCR listings
into .ASM programs.  This will facilitate your own enhancements and
experimentation.  To assist you in this, jump and call labels are
included in the comment sections of the script listings.  However,
there are a number of other considerations involved in converting
the .SCR file to an .ASM format (such as using SHORT jumps, specifying
numbers with the H suffix for hexadecimal, substituting labels for data
references, etc.), so you should only try this if you know what's
going on.  (Again, you can use a word processor to "block" and "write"
the listings out to files with the extension .ASM, and run them with
your Macro Assembler.)

- - - - -
     NOTE:  I don't have an EGA/ECD.  Therefore, I have not run and/or
tested any of the files contained in this article.  I have carefully
typed the .SCR/.ASM files found below, but I can't guarantee that they
are accurate.  -DRW-
- - - - -

Disabling ANSI.SYS

     If you have device drivers or remain-resident programs that do
things with the display, particularly with colors, you should first
try out these EGA utilities without loading those other programs.
You'll see later, for instance, that the EGA has alternative methods
for coloring your display.  In particular, you'll want to try out the
utility programs without ANSI.SYS.  ANSI.SYS always assumes that the
display is 25 lines long, and in Part 2 of this article you'll be
experimenting with some displays that are not 25 lines long.  ANSI.SYS
also does not correctly determine the starting address for different
video pages.


Video Modes

     The EGA supports a variety of video modes, including all those
supported by the original Color/Graphics Adapter (CGA) and Monochrome
ADapter.  Additional EGA modes provide higher-resolution graphics with
more colors.  There are all the video modes supported by the EGA.

Mode   Type    Display   Resolution   Chars   Box     Colors   Pages
----   ----    -------   ----------   -----   ---     ------   -----
0&1    Text      CD        200x320    25x40    8x8      16       8
                 ECD       350x320    25x40   14x8     16/64     8

2&3    Text      CD        200x640    25x80    8x8      16       8
                 ECD       350x640    25x80   14x8     16/64     8

4&5    Graph   CD&ECD      200x320    24x40    8x8       4       1

 6     Graph   CD&ECD      200x640    25x80   14x8       2       1

 7     Text     MONO       350x720    25x80   14x9       4       8

8,9,10      ----- PCjr modes not supported by EGA -----
11&12   ----- Used internally by EGA for loading fonts -----

 13    Graph   CD&ECD      200x320    25x40    8x8       16     2 (64K)
                                                                4 (128K)
                                                                8 (256K)

 14    Graph   CD&ECD      200x640    25x80    8x8       16     1 (64K)
                                                                2 (128K)
                                                                4 (256K)

 15    Graph    MONO       350x640    25x80   14x8        4     1 (64K)
                                                                2 (128K)

 16    Graph    ECD        350x640    25x80   14x8  4/64 (64K)  1 (128K)
                                                   16/64 (128K) 2 (256K)

The video modes available on your EGA depend upon the type of monitor
attached and the amount of memory installed on the adapter board.  The
Resolution column indicates the number of displayable scan lines (going
down the screen) and the number of displayable dots (going across the
screen).
    The number of scan lines that the EGA displays is either 200 (which
is the same as the CGA) or 350 (which is the same as the Monochrome
Adapter).  An EGA attached to a regular Color Display cannot use the
the 350-line modes.  An EGA attached to an ECD can use either 200 or
350 lines.  The difference between 200 and 350 scan lines is obvious
on the screen; you can count the individual scan lines on your screen
in a 200-line display, but with 350 lines you cannot.  These two basic
modes of operation are also different in ways other than resolution.
     If you have 25 lines of characters displayed on your screen (which
is normal but definitely not the only way you can use your EGA), the
Box column shows the resolution available for each character.  If you
have an ECD (or compatible) attached to your EGA and you get only an
8 by 8 character box, your EGA DIP switches are not set correctly.
     EGAMODE.COM will let you switch to any video mode supported by
your monitor.  After you create EGAMODE.COM from EGAMODE.SCR using
DEBUG, you can run the program by typing:

EGAMODE mode

where mode is the video mode (expressed as a decimal number) to which
you want to switch.  The normal modes for the DOS command level and
most programs that use text are 3 (for color displays) and 7 (for
monochrome).  You can run EGAMODE without a parameter to see what
your current mode is.

N EGAMODE.COM
A 100
JMP   011B              ;Skip Label
DB    "Current Video Mode is 00$"
MOV   BX,005D           ;Parameter
MOV   DH,0A             ;Set DH to 10
SUB   AL,AL             ;Accumulate number
MOV   CX,0003           ;Up to 3 numbers
MOV   DL,[BX]           ;GETLOOP:
SUB   DL,30             ;Subtract "0"
JB    0138              ;Jump if not number
MUL   DH                ;Multiply by 10
ADD   AL,DL             ;Add to accumulation
INC   BX                ;Point to next one
LOOP  0125              ;LOOP GETLOOP
CMP   BX,+5D            ;See if no parameter
JZ    0141              ;JZ SKIPSET
SUB   AH,AH             ;Set video mode
INT   10                ;  through BIOS
MOV   AH,0F             ;SKIPSET:
INT   10                ;Get video mode
AND   AX,007F           ;Wipe out high bit
DIV   DH                ;Divide by 10
ADD   [0118],AX         ;Save in text
MOV   DX,0102           ;Point to text
MOV   AH,09             ;Write to screen
INT   21                ;  through DOS
INT   20                ;Terminate

R CX
57
W
Q

     You can also use the DOS MODE command to switch between video
modes, but that command is limited to the text modes and uses key words
rather than numbers.  The MODE parameters and the corresponding video
modes are BW40 (mode 0), CO40 (mode 1), BW80 (mode 2), CO80 (mode 3),
and MONO (mode 7).  Modes 0 through 6 are the CGA modes.  Mode 7 is
the Monochrome Adapter mode.  All of these modes are supported by the
EGA when it is connected to the proper monitor.
     Modes 8, 9, and 10 are the additional PCjr graphics modes that are
not supported by the EGA BIOS.  Modes 11 and 12 are used internally by
the EGA BIOS to load fonts into the adapter.
     You'll notice that the table begins with pairs of modes that are
the same: 0 and 1, 2 and 3, 4 and 5.  On the EGA both modes in each
pair are identical, as they were identical on the CGA if you used its
regular, direct-drive connector.  However, if you used the composite
video output on the CGA with a black-and-white monitor, modes 0, 2,
and 5 disabled the color-burst signal.  The EGA does not support
composite monitors.


Experimenting

     If you experiment with EGAMODE, you may be surprised that the EGA
BIOS allows you to change the mode to one that your monitor doesn't
support.  If you happen to accidentally do it, close your eyes and
enter EGAMODE 3 (for color) or EGAMODE 7 (for monochrome) to get
things back to normal.
     You'll notice that you can switch to graphics modes at the DOS
command level, but the screen operations are significantly slower.
This is because the BIOS has to construct the dot patterns of each
character on the screen instead of just writing the ASCII code of the
character to display memory.  If you run an applications program that
does not set the video mode but writes directly to the display, you'll
get garbage on your screen if you enter it in a graphics mode.
     Normally when the EGA switches to a new mode, it clears out all
video memory.  However, if you add 128 to the mode number when running
EGAMODE, the EGA BIOS will set the mode but will retain the contents
of the screen memory buffer, so the screen will not be cleared.  (The
PCjr BIOS functions similarly.)  However, the cursor will be returned
to its home position in the upper-left-hand corner.  If you're in mode
3, you should try entering:

EGAMODE 131

to see what happens.  The screen will still have all the contents, but
the cursor will now be up at the top.  For a more interesting effect,
try:

EGAMODE 144

This sets the EGA to mode 16 without clearing memory.  You'll have some
snowy garbage scattered on your display.  Those are the characters
stored in the EGA memory that are now being interpreted as dots.  As
you can see, the text and graphics modes are very different.  Now go
back to mode 3 with:

EGAMODE 131

The characters from the graphics mode now appear as various colored
blocks on the screen.
     Don't run other programs after resetting the mode with 128 added
to it.  When a program reads the mode through the BIOS, the BIOS
reports this high-numbered mode.  This may completely confuse an
applications program.


The EGA and Other Adapters

     If you have your EGA connected to a color monitor, you can still
have a Monochrome Adapter in your system as well.  Similarly, if your
EGA is connected to a monochrome display, you can also have a CGA in
your system.  EGAMODE will not switch between the two adapters,
however.  Use the DOS MODE command to do that.
    If you have a Hercules Graphics Card (HGC) attached to a monochrome
monitor, it too can coexist with an EGA attached to a color display.
However, you'll want to use EGAMODE before running any program that
uses the "page 1" graphics of the HGC.  Monochrome mode 7 uses memory
starting at segment address B000h for the display.  Color modes 0
through 6 use memory starting at segment address B800h.  No conflict
so far.  However, the HGC can use both "page 0" (starting at B000h)
and "page 1" (at B800h) for graphics.  Many programs that support the
HGC use "page 1" graphics.  You may know about this because you run
HGC FULL before you use them to enable this second graphics page.
     HGC "page 1" graphics would normally conflict with a CGA (and
hence an EGA) board.  However, the EGA graphics modes 13 through 16
all use display memory beginning at A000h.  This allows you to move
the EGA out of the way before you use Hercules graphics.  To do this,
you would enter:

MODE CO80
EGAMODE 16
MODE MONO

The first program switches to the EGA in mode 3 (in case you're not
already there); the second sets the EGA mode to 16 (which uses segment
A000h); and the third program switches to the monochrome display.  (If
your EGA is attached to a regular Color Display, use EGAMODE 14
instead.)  Now you can use Hercules graphics without restriction.  If
you have some batch files with HGC FULL statements, you can add these
three lines to the batch file before the HGC FULL line.
     After you're done and want to return to the EGA, use:

MODE CO80

This statement can be placed after an HGC HALF statement in a batch
file.
     You won't need to do this for all programs that use Hercules
graphics.  But if you ever see garbage appear on a color display
attached to an EGA while graphics appear on a monochrome display
attached to a HGC, that means there's a memory conflict.


Pages and Pages

     The column called Pages shows the number of video pages on the
EGA for various modes and memory sizes.  Particularly in character
modes, the display you see on your screen takes up only a small amount
of the total EGA memory.  The extra memory is used for other video
pages.
     EGAPAGE.COM lets you change the video page from the DOS command
level.  The BIOS keeps track of cursor positions for 8 separate video
pages.  When a video mode is first set, all of the cursors are set to
the upper-left-hand corner.  To switch to page 1, execute:

EGAPAGE 1

To go back to page 0, execute:

EGAPAGE 0

EGAPAGE.COM doesn't accept page numbers higher than 7, but it also
doesn't check to see whether the current video mode supports less than
8 pages. Without a parameter, EGAPAGE tells you the current video page.

N EGAPAGE.COM
A 100
JMP   011A              ;Jmp BEGIN
DB    "Current Video Page is 0$"
MOV   AL,[005D]         ;BEGIN: Convert
SUB   AL,30             ;  parameter
JB    0129              ;JC GETPAGE
CMP   AL,07             ;See if above 7
JA    0129              ;JA GETPAGE
MOV   AH,05             ;Set page
INT   10                ;  through BIOS
MOV   AH,0F             ;GETPAGE:
INT   10                ;  through BIOS
ADD   [0118],BH         ;Store in string
MOV   DX,0102
MOV   AH,09             ;And display it
INT   21
INT   20                ;Terminate

R CX
3A
W
Q

     EGAPAGE is useful when you have something on your screen that you
want to return to later.  Just change the video page, do your other
tasks, and then come back to the original video page.  Resetting the
video mode, however, blanks out the contents of all video pages.
     (ANSI.SYS users, take note: The EGA uses different starting
addresses than the CGA for these video pages.  Although the starting
address is stored in the BIOS data area, ANSI.SYS doesn't use it and
will not correctly handle anything other than page 0 on the EGA.)


The 64-Color Palette

     For the 350-line modes, the available colors are indicated as
16/64.  This means that only 16 colors can be displayed simultaneously
on the screen, but these 16 colors may be selected from 64 colors.  In
the video modes that use 200 scan lines, only 16 colors are possible.
     That 64 colors are available only on the ECD in 350-line modes is
not a coincidence or the whimsy of the people who designed the EGA.
The ECD runs at a faster horizontal sync rate in order to fit in all
350 lines.  The display is triggered to use this higher horizontal
sync rate by the polarity of the vertical sync signal.  At the same
time, it uses 6 color signals on the video connector instead of just
the 4 that the regular Color Display uses.  (The Monochrome Display
uses two signals for color: Video and Intensity.)
     The 4-bit color code in 200-line modes is called IRGB.  The RGB
part of this stands for Red, Green, and Blue, and I stands for
Intensity.  Thus, 16 colors are available:  low- and high-intensity
versions of 8 colors.
     The 6-bit color code in 350-line modes can be represented as
"rgbRGB" with both primary (RGB) and secondary (rgb) red, green, and
blue signals.  The lowercase letters are sometimes referred to as
"1/3 intensity" (which are darker) and the uppercase letters are
"2/3 intensity" (brighter).  In both cases, these are digital signals,
either on or off, so the 350-line modes have a total of 64 colors.


CGA Color

     To understand how color works on the EGA and what we can do with
color, this is what we know about color on the CGA.
     In CGA text modes, each character stored in the adapter memory
has a corresponding 1-byte "attribute" that controls the foreground
and background colors of the character.  The lower 4 bits of this
attribute contain an IRGB code for the foreground color, which is the
color of the character.
     The next highest 3 bits of the attribute contain an RGB code
(nonintensified) for the background color.  The highest bit controls
blinking.
     In this respect, the EGA works the same way and uses the same
attribute codes as the CGA.
     (On the CGA, you could disable blinking, and thus make the higher
4 bits a full IRGB code for the background, by writing the value 09h
to register 3D8h.  The EGA does not support this register, but you can
do the same thing with a BIOS call:

MOV AX,1003h
MOV BL,0
INT 10h

This enables background intensity.  A value of 1 in BL enables
blinking.)
     The big difference between the CGA and the EGA in handling color
is this: On the CGA, the 4 color bits represented by the IRGB code go
directly to the video connector and then the monitor.  On the EGA, the
4-bit color code passes through an "Attribute Controller" before going
out to the monitor.  In 200-line modes, this Attribute Controller can
translate a 4-bit IRGB code into any other 4-bit IRGB code.  In 350-
line modes, the Attribute Controller can translate it into any 6-bit
rgbRGB code.  The Attribute Controller functions as a lookup array.
The translation is controlled by values loaded into the EGA "palette
registers."
     This table shows the default mapping of the IRGB codes into
rgbRGB codes in the EGA 350-line modes.  The binary representation is
helpful because it shows how the bits correspond directly to the
letters in "IRGB" or "rgbRGB."  The octal (base 8) representation for
the rgbRGB code is actually more useful because the first digit
represents the 1/3-intensity rgb signal and the second digit is the
2/3-intensity RGB signal.

                    IRGB code           Default rgbRGB mapping
                -------------------     ----------------------
Color           binary  octal   hex     binary    octal    hex
-----           ------  -----   ---     ------    -----    ---
Black            0000     00     00     000000      00      00
Blue             0001     01     01     000001      01      01
Green            0010     02     02     000010      02      02
Cyan             0011     03     03     000011      03      03
Red              0100     04     04     000100      04      04
Magenta          0101     05     05     000101      05      05
Brown            0110     06     06     010100      24      14
White            0111     07     07     000111      07      07
Dark Grey        1000     10     08     111000      70      38
Light Blue       1001     11     09     111001      71      39
Light Green      1010     12     0A     111010      72      3A
Light Cyan       1011     13     0B     111011      73      3B
Light Red        1100     14     0C     111100      74      3C
Light Magenta    1101     15     0D     111101      75      3D
Yellow           1110     16     0E     111110      76      3E
Bright White     1111     17     0F     111111      77      3F

     Note that for intensified colors, the default mapping combines
the 2/3-intensity signal with all three 1/3-intensity signals so that,
at the bottom of the chart, the "bright white" color has all bits
turned on.  Note also that the EGA brown is faked; it uses a dark green
and light red signal.  Forth-eight other possible rgbRGB codes aren't
used at all in this default mapping.
     On the DOS command level, and in many programs that don't use
color, characters are represented with an attribute code of 07h.  This
means the background is black (0) and the foreground is white (7).
However, the EGA maps these two codes into black and white only by
default.  We can change the mapping to whatever we want by loading
different values into the EGA palette registers.  That's what
EGACOLOR.COM does.

N EGACOLOR.COM
A 100
MOV   AX,[005D]         ;1st parameter
CALL  0117              ;CALL CONVERT
MOV   BL,AL             ;Save in BL
MOV   AX,[006D]         ;2nd parameter
CALL  0117              ;CALL CONVERT
MOV   BH,AL             ;Save in BH
MOV   AX,1000           ;Change palette
INT   10                ;  through BIOS
INT   20                ;Terminate
SUB   AL,30             ;CONVERT:
CMP   AH,20             ;Check if one digit
JZ    0127              ;JZ ALLDONE
SUB   AH,30             ;Convert to binary
MOV   CL,03             ;Three bit shift
SHL   AL,CL
ADD   AL,AH             ;Put two together
RET                     ;ALLDONE:

R CX
28
W
Q

     EGACOLOR.COM takes two arguments, both of them octal numbers.  The
first two-digit number is the IRGB color value from 0 through 17.  The
second is the rgbRGB color value from 00 through 77 that you want the
IRGB code translated into. Leading zeros are not required. For example:

EGACOLOR 00 01
EGACOLOR 07 76

changes everything normally displayed as black to dark blue, and
everything normally white to high-intensity yellow.  If you're not
using any other program to control color and run these two programs,
your screen will suddenly burst into yellow-on-blue colors.  The color
translation is done in the EGA hardware.
     If you have your EGA connected to a regular Color Display (which
supports only 200 scan lines and 16 colors), you can still use EGACOLOR
but only with the 4-bit IRGB codes in octal (i.e., 00 through 17) for
the second argument.
     If you change the video mode with EGAMODE, the colors go back to
normal.  A mode reset always loads up the EGA palette registers with
the default mapping.  The best thing about using the EGA palette
registers to control color is that programs that do not reset the
video mode will still use the colors you've set.  Later we'll see how
to get the palette registers loaded even for programs that set the
video mode.
     By running EGACOLOR 64 times with the command:

EGACOLOR 0 XX

where XX is an octal number from 00 through 77, you can see all 64
colors as background colors.  However, there's a better method.


The EGA's 64 Varieties

     You can't display all 64 colors at once on the EGA.  It's just
impossible.  But with a little "gonzo programming," it can be done.
EGAPALET.COM displays all 64 EGA colors on an ECD.  If you have a PC
AT, substitute a value of 2B for 22 in the line near the top that
begins with DB.

N EGAPALET.COM
A 100
JMP   0103              ;JMP SHORT BEGIN
DB    22
CLD                     ;BEGIN:
MOV   AX,0003           ;Set mode to 3
INT   10                ;  through BIOS
MOV   AX,B800           ;Set ES to B800
MOV   ES,AX             ;  display segment
SUB   DI,DI             ;Start at top
MOV   AL,DB             ;Use block character
MOV   BH,19             ;Number of lines
SUB   AH,AH             ;LOOP2:
MOV   BL,08             ;Colors per line
MOV   CX,000A           ;LOOP1: 10 characters
REPZ                    ;Write to display
STOSW
INC   AH                ;Next color
DEC   BL                ;Decrement counter
JNZ   0118              ;JNZ LOOP1
DEC   BH                ;Decrement counter
JNZ   0114              ;JNZ LOOP2
MOV   BH,[0102]         ;Get "Count" value
MOV   DX,03DA           ;Status port
MOV   AX,0040           ;Set DS to BIOS
MOV   DS,AX             ;  data area
STI                     ;MAINLOOP:
SUB   AH,AH             ;Start colors at 0
MOV   BL,01             ;Temporary "Count"
CLI                     ;VERTWAIT:
IN    AL,DX             ;Wait for vertical
TEST  AL,08             ;  retrace
JZ    0138              ;JZ VERTWAIT
IN    AL,DX             ;ENDVERT:
TEST  AL,08             ;Wait for end of it
JNZ   013E              ;JNZ ENDVERT
IN    AL,DX             ;HORIZWAIT:
SHR   AL,1              ;Wait for horizontal
JNB   0143              ;JNB HORIZWAIT
DEC   BL                ;Decrement "Count"
JZ    0153              ;JZ BLITZ
IN    AL,DX             ;ENDHORIZ:
SHR   AL,1              ;Check horizontal retrace
JB    014C              ;JZ ENDHORIZ
JMP   0143              ;JMP HORIZWAIT
MOV   CX,0000           ;BLITZ:
MOV   DL,C0             ;Palette register
MOV   AL,AH             ;BLITZLOOP:
AND   AL,07             ;Output palette
OUT   DX,AL             ;  number 0 - 7
MOV   AL,AH             ;Output color value
OUT   DX,AL             ;  00 - 3Fh
INC   AH                ;Next color
LOOP  0158              ;LOOP BLITZLOOP
MOV   AL,20             ;Enable video
OUT   DX,AL
MOV   DL,DA             ;Reset DX
MOV   BL,BH             ;"Count" value
CMP   AH,40             ;See if end of colors
JNZ   0143              ;JNZ HORIZWAIT
MOV   CX,[001A]         ;Check if key struck
CMP   CX,[001C]
JZ    0133              ;JZ MAINLOOP
MOV   AX,0003           ;Reset video mode
INT   10
INT   20                ;Terminate

R CX
81
W
Q

     When you run the program, you should have 8 rows with 8 different
colors in each.  The display is much more stable on an AT; the
flickering and wavy lines between the rows of color on a PC or XT is
normal.  If the bottom row is larger than the rest on your machine,
increase that number following DB a bit.  If the bottom row is smaller
than the rest (or if you don't see rows at all), decrease the number.
Make it no bigger than 2Bh.
     You may have to turn up your contrast and brightness controls to
see the full range of colors.  Even then, some of the colors may appear
very similar.  If you have a magnifying glass or camera close-up lens,
you can check that they do indeed use different dots.  Press any key
to leave the program.
     The EGAPALET program actually uses only 8 color values, 0 through
7, and displays 8 columns of blocks using these values.  However, every
1/480 of a second, EGAPALET changes these 8 palette registers, so the
colors on your screen change.  It controls the timing by counting
horizontal scan retraces.
     The default EGA color mapping uses the top row and bottom row of
EGAPALET's 64 colors, except for brown, which is in the third row,
fifth from the left.  If you see a color you'd like to use in EGACOLOR,
you can determine its octal code in this way:  Count down to the row
from the top, starting at zero.  That's the first digit.  Count over
to the column from the left, starting at zero.  That's the second
digit.  (Octal is better for colors.)


The EGA Border Problem

     In 350-line modes the EGA also allows you to set the border
(called the "overscan register") to any of the 64 colors.  EGABORD.COM
does this.

N EGABORD.COM
A 100
MOV   AX,[005D]         ;Get parameter
SUB   AL,30             ;Convert to binary
CMP   AH,20             ;Check for blank
JZ    0113              ;JZ ALLDONE
SUB   AH,30             ;Convert 2nd digit
MOV   CL,03             ;Shift it 3 spaces
SHL   AL,CL
ADD   AL,AH             ;Stick two together
MOV   BH,AL             ;ALLDONE:
MOV   AX,1001           ;Set border through
INT   10                ;  BIOS
INT   20                ;Terminate

R CX
1C
W
Q

     Run it by typing:

EGABORD XX

where XX is the two-digit octal code for an rgbRGB color.  The results,
however, are pathetic.  Not only is the border very skimpy, but using
it causes some shading problems in the left two-thirds of the display.
(If your EGA is attached to a regular Color Display, you don't have
this problem.  But in that case you can set your border to only 1 of
the 16 IRGB colors.)
     Borders on the EGA are a problem, and the best way to solve the
problem is to convince yourself that an EGA cannot display borders in
350-line modes.  When you know something is impossible, it may cease
to bother you.  After a while, you may even prefer the black border.
Let's go through some display arithmetic to prove it.  Then you can
relax knowing you're not missing out on anything.
     In 200-line compatibility modes, the EGA (like the CGA) uses the
14.318-MHz clock available on the system bus for the dot clock.  At
each pulse of the dot clock, the adapter sends a color signal to the
display.  But, in 350-line enhanced modes, the EGA has to write more
dots to the display in the same amount of time, so the EGA uses an
on-board 16.257-MHz crystal for the dot clock.
     This already looks ominous: the EGA displays 75 percent more scan
lines with only a 13.5 percent higher dot clock frequency.
     In 200-line compatibility modes, the horizontal scan rate is
15.75 kHz.  This is the rate at which each scan line of the screen is
displayed.  Dividing the dot clock frequency (14.318 MHz) by the
horizontal scan rate results in 909 dots, the equivalent of 114
characters.  The displayable area uses only 640 dots for 80 characters.
The horizontal retrace requires about 8 characters.  The 26 characters
left over are in the border area.  If you divide the horizontal scan
rate (15.75 kHz) by the vertical scan rate (60 Hz), you get 262 lines.
The displayable area needs only 200 lines (25-character rows with 8
scan lines each).  Again, some of the leftovers occur during the
vertical retrace (when the signal jumps from the lower-right-hand to
the upper-left-hand corners of the display), but the rest are
available for the top and bottom border region.
     In 350-line modes on the ECD, both the dot clock frequency and
the horizontal scan rate are slightly higher.  The 16.257-MHz dot
clock frequency divided by the 21.85-kHz horizontal scan rate results
in 744 dots or 93 characters, of which 80 are displayed and about 10
occur during the horizontal retrace.  That leaves about 3 characters
for the left and right borders.  The horizontal scan rate (21.85 kHz)
divided by the vertical scan rate (60 Hz) shows that the EGA can
display 364 lines: 350 of them are used in the display and 13 of them
occur during the vertical retrace.  That leaves about 1 scan line for
a top and bottom border.
     The reason the EGA can't do borders in 350-line modes is thus
very simple: Very soon after it finishes a scan line, it begins the
horizontal retrace.  Almost immediately after completing the last scan
line, it makes a vertical retrace.  The border area is untouched by
the dot gun.
     In fact, because of the very tight timing restrictions, the
display is not fully blanked during the whole horizontal retrace.
That's why you get a faint background shading when you try to display
a border.  The unwanted shading is actually the border color being
displayed during the horizontal retrace.  It's faint because it's
stretched out.


Now for a Real Border

     Sooner or later, you are going to read about a way to do a real
border on the EGA, so you might as well read about it here.  Opinion
is divided over whether this technique can damage your monitor.  Do
you really want a border?
     OK, so you do.  Although the ECD is designed for a horizontal
sync rate of 21.85 kHz, it has some tolerances.  Most ECDs can run
about 5 percent lower.  If we program the EGA to do so, we'll be able
to fit in enough dots to make a border.
     (Although the ECD normally runs at a vertical sync rate of 60 Hz,
it is actually rated for vertical syncs between 50 Hz and 60 Hz.  Thus,
getting a top and bottom border is fairly easy.  It's the left and
right borders that cause the problem.)
     EGATIME.COM is designed to be run in mode 3 with an ECD attached,
but it does not check to make sure you are in compliance with these
requirements.  It takes a one-digit parameter from 0 to 7 to select
from 8 sets of possible values to load into the EGA's CRT Controller
registers.  These change the basic timings of the EGA.  The lower the
number you give to EGATIME, the better the border but the less chance
your ECD can handle it.  The parameter of 7 loads the normal values.

N EGATIME.COM
A 100
JMP   01A3
DW 6000,5602,2003,5604,5C05,8C06,6E10,2B11,6E15,1A16
DW 5F00,5502,3F03,5504,5B05,8C06,6E10,2B11,6E15,1A16
DW 5E00,5402,3E03,5404,5A05,8C06,6E10,2B11,6E15,1A16
DW 5D00,5302,3D03,5304,5905,8C06,6E10,2B11,6E15,1A16
DW 5C00,5302,3C03,5304,5805,8C06,6E10,2B11,6E15,1A16
DW 5F00,5502,3F03,5504,5B05,7C06,6610,2B11,6615,1216
DW 5D00,5302,3D03,5304,5905,7C06,6610,2B11,6615,1216
DW 5B00,5302,3703,5104,5B05,6C06,5E10,2B11,5E15,0A16
MOV   AL,[005D]         ;Get parameter
AND   AL,07             ;Use lowest 7 bits
MOV   AH,14             ;Multiply by 20
MUL   AH
ADD   AX,0103           ;Add offset of beginning
MOV   SI,AX             ;Make sure that the source
MOV   DX,03D4           ;CRT Controller Register
MOV   CX,000A           ;10 words to load
CLD
LODSW                   ;OUTLOOP: Get byte
OUT   DX,AX             ;Output to register
LOOP  01B8              ;Loop OUTLOOP
INT   20                ;Terminate

R CX
BE
W
Q

     You can experiment with EGATIME.COM by first running:

EGABORD 1

to select a blue border.  Then try:

EGATIME 6

and if that doesn't make your screen look like a television that needs
servicing, try something lower. You can always get back to normal with:

EGATIME 7

If you really want a border, using EGATIME to get it is up to you.
If you decide to use it, you may also want to add EGABORDR to your
AUTOEXEC.BAT file.  This is a remain-resident program that lets you
change your border to any of the 64 colors from your keyboard.  Alt-]
advances through the 64 colors, and Alt-[ goes backward.

N EGABORDR.COM
A 100
JMP   013A              ;JMP SHORT INIT
DB    0
DW    0, 0
PUSH  AX                ;NEXINT9:
PUSH  BX
CS:
MOV   BH,[0102]         ;Get current color
IN    AL,60             ;Get scan code of key
CMP   AL,1A             ;Check if [
JZ    011C              ;JZ DECREMENT
CMP   AL,1B             ;Check if ]
JNZ   0133              ;JNZ SKIPALL
INC   BH                ;Increment the color
JMP   011E              ;JMP SHORT CONTINUE
DEC   BH                ;DECREMENT:
AND   BH,3F             ;Only last six bits
MOV   AH,02             ;Check for ALT key
INT   16
TEST  AL,08
JZ    0133              ;JZ SKIPALL
MOV   AX,1001           ;Set border
INT   10                ;  through BIOS
CS:
MOV   [0102],BH         ;Save new color
POP   BX
POP   AX
CS:
JMP   FAR [0103]        ;Do old Int 9
MOV   AX,3509           ;INIT: Get old
INT   21                ;  Int 9
MOV   [0103],BX         ;Save it
MOV   [0105],ES
MOV   DX,0107           ;Set new Int 9
MOV   AX,2509
INT   21
MOV   DX,013A           ;Terminate and
INT   27                ;  stay resident

R CX
54
W
Q


Permanent Color Mapping

     EGACOLOR.COM maps attribute colors into screen colors, but these
color mappings revert to the defaults whenever a program changes the
video mode.  When the BIOS resets the video mode, it loads the EGA
registers and sets the values in the BIOS data area based on a set of
"video parameters" that include the default colors.  These video
parameters are normally located in the EGA BIOS.  However, you can
direct the BIOS to use an alternative set of video parameters by
creating a remain-resident program with the parameters and setting a
pointer located in the BIOS data area to point to it.  The EGA BIOS
is set up to allow you to do things like this legitimately and easily.
     On page 107 of the BIOS listing in the EGA Technical Reference,
you'll see a pointer called SAVE_PTR stored at memory location
0000:04A8.  It points to a set of seven other double-word (i.e.,
segment and offset) pointers, called DWORD_1 through DWORD_7.  DWORD_5
through DWORD_7 are reserved for future use.
     DWORD_1 points to a 1472-byte location in memory that contains
64 video parameters for each of the 23 video modes supported by the
EGA.  There are 17 video modes, 0 through 16.  The EGA does not support
modes 8 through 10 (the PCjr modes) and uses modes 11 and 12 internally
when loading fonts.  But modes 0 through 3 are for the 200-scan-line
versions when a regular Color Display is attached to the EGA.  Modes
15 and 16 are for EGAs with only 64K of memory.  After these 17 modes,
the table (see above) contains values for modes 15 and 16 when 128K
or more is attached to the EGA.  Finally, 350-scan-line versions of
modes 0 through 3 are included when an EGA is equipped with an ECD.
     Although page 103 of the EGA Technical Reference indicates in
large letters that the Interrupt 43h vector points to the Video
Parameters table, this is not so.  Interrupt 43h actually points to
the Graphics Character Table, which is the font used to construct
characters in graphics modes.  Interrupt 44h, which the EGA Technical
Reference mistakenly indicates as pointing to this Graphics Character
Table, is not used by the EGA BIOS.  This change may seem odd since
Interrupt 44h is used by the PCjr to point to the Graphics Character
Table.
     For each video mode, the 64 video parameters include the values
loaded into the palette registers.  But if we tried to change the
table directly, it wouldn't work since they are stored in the EGA ROM
BIOS, and we can't write into ROM.
     EGAPRMOV (which stands for "EGA Parameter Move") simply moves the
set of seven pointers and the entire video parameter table into RAM.
It need be executed only once during your PC session.

N EGAPRMOV.COM
A 100
CLD
SUB   AX,AX
MOV   ES,AX             ;Set ES to 1st segment
ES:
LDS   SI,[04A8]         ;Get SAVE_PTR
MOV   DI,013C           ;Set up for transfer
ES:
MOV   [04A8],DI         ;New SAVE_PTR
ES:
MOV   [04AA],cs
PUSH  CS
POP   ES
MOV   CX,000E           ;14 double words
REPZ
MOVSW
ES:
LDS   SI,[013C]         ;Get DWORD_1 pointer
MOV   DI,0158           ;Set up for transfer
ES:
MOV   [013C],DI         ;New DWORD_1
ES:
MOV   [013E],CS
PUSH  CS
POP   ES
MOV   CX,05C0           ;23 * 64 bytes
REPZ
MOVSB
MOV   DX,0718           ;Keep resident
INT   27                ;  and exit

R CX
3C
W
Q

     Now we can manipulate the video parameters.  EGACOSET.COM ("EGA
Color Set") replaces the default palette values for video mode 3 (in
350-line mode) with those of your own choosing.  The two lines with
the 16 hex numbers are yours to customize.  For instance, if you use:

DB  01,01,02,03,14,05,06,3E
DB  30,31,32,33,34,35,36,32

the EGA will map color 00 (black) to 01 (blue), color 07 (white) will
be mapped to 3E (bright yellow) and color 0F (bright white) will be
mapped to 32 (bright green).

N EGACOSET.COM
A 100
CLD
SUB   AX,AX
MOV   ES,AX             ;ES to low memory
ES:
LES   DI,[04A8]         ;Get SAVE_PTR
ES:
LES   DI,[DI]           ;Get DWORD_1
MOV   SI,011B           ;Values to move in
ADD   DI,05A3           ;Offset for mode 3
MOV   CX,0010           ;16 bytes
REPZ
MOVSB
INT   20
DB    00,01,02,03,04,05,14,07
DB    38,39,3A,3B,3C,3D,3E,3F

R CS
2B
W
Q

     If your EGA is attached to a regular Color Display, change the
line reading ADD DI,05A3 to ADD DI,00E3 and use only color values that
range from 00 through 1F in the DB lines.
     When you first execute EGACOSET.COM, nothing will happen.  But if
you then change the video mode with an

EGAMODE 3

your screen will display yellow-on-blue.
     Once EGACOSET is executed, the EGA BIOS will load these values
into the palette registers whenever mode 3 is set.  When a program
tries to display a white-on-black character, yellow-on-blue will show
up instead.  EGACOSET is not resident like EGAPRMOV, so you can
experiment by running different versions of it without using additional
memory.
     If you put both EGAPRMOV and EGACOSET in your AUTOEXEC.BAT file,
almost every program that uses black-and-white in video mode 3 will use
your customized color scheme instead.
     There are exceptions, however.  Some "EGA-aware" programs load the
palette registers themselves after they load.  Such programs include
Microsoft Word 2.0 and the new EGA drivers for 1-2-3 Release 1A.
BASICA 3.2 loads OK but then changes the palette registers back to
normal on exit.
     If you've also found an EGATIME setting that works for you,
EGABOSET.COM will also adjust the CRT Controller registers to these
values when mode 3 is set.  EGABOSET.COM assumes that EGAPRMOV has
been loaded.  It's set up for the same values as EGATIME 0 and a blue
border.  If EGATIME 0 didn't work but something else did, count down
the lines of numbers beginning with DW in EGATIME.SCR (starting at 0)
and substitute the number in the line beginning with DW in
EGABOSET.SCR.  If you want a border color other than blue, change the
number after the line that begins DB in EGABOSET to the hex rgbRGB
code for the border color you want.

N EGABOSET.COM
A 100
CLD
SUB   AX,AX
MOV   ES,AX             ;ES to low memory
ES:
LES   DI,[04A8]         ;Get SAVE_PTR
ES:
LES   DI,[DI]           ;Get DWORD_1
ADD   DI,0580           ;Offset for mode 3
MOV   SI,012B           ;Values to move in
MOV   CX,000A           ;10 bytes first
LODSW                   ;STORELOOP: Get byte
MOV   BL,AL             ;Use low byte
SUB   BH,BH             ;  for offset
MOV   AL,AH             ;Use high byte for value
ES:
MOV   [BX+DI+0A],AL     ;Save it
LOOP  0117              ;Loop STORELOOP
LODSB                   ;Get border color
ES:
MOV   [DI+34],AL        ;Save it
INT   20                ;Terminate
DW 6000,5602,2003,5604,5C05,8C06,6E10,2B11,6E15,1A16
DB 01

R CX
40
W
Q

     Do not use EGABOSET with a regular Color Display attached to an
EGA.  If you want a border color set automatically, go back to
EGACOSET.  Change the line reading MOV CX,0010 to MOV CX,0012.  At the
end of the second line of numbers that start with DB, add a comma, 08,
another comma, and the color value of the border you want.  The line
after R CX should be changed from 2B to 2D.