;    Customized Logitech Mouse Menu For QFiler (c)
;    QFiler is a product of Jamestown Software,
;                           2508 Valley Forge Dr.
;                           Madison, WI 53719
;
BEGIN LeftB, menu2, menu1, LeftM, RightM, UpM, DownM, 64, 36
;
; mouse motions emulate arrow keys, left button marks/unmarks files
; except when in submenu mode.  Horizontal sensitivity lowered to 64
; to prevent excessive left/right window switching while scrolling
; thru directories.  Right button brings up Custom Mouse Menu which
; emulates all shifted/unshifted function key strokes and most Ctrl-key
; functions.  Pressing both mouse buttons displays a single-column menu
; which replicates QF's bottom-line default menu.
;
LeftM:  TYPE 0,75
RightM: TYPE 0,77
UpM:    TYPE 0,72
DownM:  TYPE 0,80

LeftB:  TYPE 0,67
;
; Customized mouse menu appears below.  Single column menu is displayed
; with upper left corner on line 1, position 18 of the screen, which
; leaves all file names visible.
;
menu1: MENU "QFiler Mouse Menu", 1, 18, 71
    OPTION "Display Subdir/Left", F3
    OPTION "Display Subdir/Right", F4
    OPTION "Sort by Name", F7
    OPTION "Sort by Extension", F8
    OPTION "Sort by Size", SF7
    OPTION "Sort by Date", SF8
    OPTION "ARC Utilities",ARC
    OPTION "List Utilities",LED
    OPTION "Execute File",CTRLE
    OPTION "DOS Shell",CTRLS
    OPTION "Printer Setup",CTRLP
    OPTION "Refresh Windows",CTRLR
    OPTION "Make Directory",F1
    OPTION "Remove Directory",F2
    OPTION "Hide File",SF3
    OPTION "UNHide File",SF4
    OPTION "Protect File",SF5
    OPTION "UNProtect File",SF6
    OPTION "Timestamp File",SF9
    MEND

F1: TYPE 0,59
F2: TYPE 0,60
F3: TYPE 0,61
F4: TYPE 0,62
F7: TYPE 0,65
F8: TYPE 0,66
SF3: TYPE 0,86
SF4: TYPE 0,87
SF5: TYPE 0,88
SF6: TYPE 0,89
SF7: TYPE 0,90
SF8: TYPE 0,91
SF9: TYPE 0,92
CTRLE: TYPE 5
CTRLS: TYPE 19
CTRLP: TYPE 16
CTRLR: TYPE 18
;
; Below is the mouse 'replica' of the Qfiler default menu.  This single-
; column menu is displayed on line 4, position 18.
;
;
menu2: MENU "Default Menu", 4, 18, 14
     OPTION "UnMarkAll",UNM
     OPTION "Copy",COP
     OPTION "Delete",DEL
     OPTION "MarkAll",MRK
     OPTION "Rename",REN
     OPTION "Execute",EXE
     OPTION "List",LED
     OPTION "VolLabel",VOL
     OPTION "Quit",QUI
     OPTION "Help",HEL
     MEND

UNM: TYPE "U"
COP: TYPE "C"
DEL: TYPE "D"
MRK: TYPE "M"
REN: TYPE "R"
EXE: TYPE "E"
VOL: TYPE "V"
QUI: TYPE "Q"
HEL: TYPE "H"
LED: EXECUTE L1,M3
L1:  TYPE "L"
;
; This is the mouse replica of the List menu
;
;
M3: MENU "List/Edit Menu", 4, 18, 32
     OPTION "<S>creen",LST
     OPTION "<E>dit",EDT
     OPTION "<P>rinter",PRN
     OPTION "<C>ancel prt",CAN
     OPTION "<L>itlbook",LIL
     OPTION "<F>indit",FND
     OPTION "<ESC> quit",QUT
     MEND

LST: TYPE "S"
EDT: TYPE "E"
PRN: TYPE "P"
CAN: TYPE "C"
LIL: TYPE "L"
FND: TYPE "F"
QUT: TYPE 27
ARC: EXECUTE L2,M4
L2: TYPE 1
;
; this is the mouse replica of the ARC menu
;
;
M4: MENU "ARChive Functions", 4, 18, 32
    OPTION "<A>dd" ,ARA
    OPTION "<E>xtract",ARE
    OPTION "<V>erbose List",ARV
    OPTION "<ESC> Quit",QUT
    MEND

ARA: TYPE "A"
ARE: TYPE "E"
ARV: TYPE "V"
