Graphic Border Macro for WordPerfect For Windows

Directions:  Save this file starting with the word "Application"
in your WordPerfect for Windows macro directory.  You may name it
GRBORDER.WCM, or give it a name of your choice.  It must have the
WCM extension.  This macro will create a border around an 8 1/2"
x 11" page.  You select any graphic from your graphic directory
to make the border.  This macro was typed from page 44 of the
WORDPERFECT FOR WINDOWS MAGAZINE August 1992 issue.  Follow
instructions at the prompts.
     
Before playing the macro check your setup.  Click: File,
Preferences, Environment.  Make sure that Auto Code Placement is
on and Confirm on Code Deletion is off.  Make the left margin 1"
and the right margin .05" if you retype the macro (Retyping is
not necessary).  Play the macro at the beginning of a new file.


                               GRBORDER.WCM


Application (WP; WPWP; Default; "WPWPUS.WCD")

RevealCodes (State: Off!)
MacroStatusPrompt (State: On!; Prompt: "Setting Initial Codes ...")
DocInitialCodes ()
PageMargins (Left: 0.5"; Right: 0.5"; Top: 0.65"; Bottom: 0.25")
Close ()
HeaderFooter (Operation: Create!; Item: HeaderB!)
MacroStatusPrompt (State: On!; Prompt: "Select graphic and choose
Retrieve")
FigureRetrieveDlg ()
MacroStatusPrompt (State: Off!)
BoxSelect (Type: Figure!; BoxNumber: "1")
BoxPosition (NewType: User!;
   Anchor: Character!;
   AutoMode: SetBoth!;
   Width: 0.833";
   Height: 0.833";
   WrapText: Yes!;
   VerticalType: Bottom!)
SelectMode (State: On!)
PosCharPrevious ()
EditCut ()
LineHeight (Type: Fixed!; Height: 0.833")
MacroStatusPrompt (State: On!; Prompt: "Creating Border ...")
CALL (row@)
HardReturn ()
CALL (sides@)
CALL (row@)
Advance (Where: ToLine!; Amount: 0.5")
Close ()
HeaderFooter (Operation: Create!; Item: FooterB!)
Advance (Where: Down!; Amount: 1")
Close ()
PageMargins (Left: 1.5"; Right: 1.5")
MacroStatusPrompt (State: Off!)
QUIT

LABEL (row@)
EditPaste ()
FOR (count; 1; count <= 7; count + 1)
   Advance (Where: Right!; Amount: 0.115")
   EditPaste ()
ENDFOR
RETURN

LABEL (sides@)
FOR (count; 1; count <= 10; count + 1)
   EditPaste ()
   LineFlushRight ()
   EditPaste ()
   HardReturn ()
ENDFOR
RETURN