HP48 Packet Program
      by KC1SX


%%HP: T(3)A(D)F(.);
DIR
  PPAR {
(-3.25,-3.1)
(3.25,3.2) X 0
(0,0) FUNCTION Y }
  RALL
    \<< .2 STIME
# 131d # 64d BLANK
PICT STO
      DO
        DO BUFLEN
        UNTIL AND
        END PICT {
# 0d # 0d } PICT {
# 0d # 6d } {
# 131d # 64d } SUB
REPL PICT { # 0d
# 58d } PICT { # 0d
# 58d } # 131d # 6d
BLANK REPL 31 SRECV
DROP 1 \->GROB REPL {
# 0d # 0d } PVIEW
CLEAR
      UNTIL 0
      END
    \>>
  W
    \<<
      DO BUFLEN AND
      UNTIL
      END
    \>>
  QUAL { { "OPEN"
    \<< "Qualifier" {
"" { 1 6 } \Ga }
INPUT CONT
    \>> } { "80"
    \<< "80" CONT
    \>> } { "40"
    \<< "40" CONT
    \>> } { "20"
    \<< "20" CONT
    \>> } { "15"
    \<< "15" CONT
    \>> } { "10"
    \<< "10" CONT
    \>> } }
  DX
    \<< "Frequency"
"" INPUT \-> F
      \<< "Call Sign"
{ "" { 1 6 } \Ga }
INPUT \-> C
        \<< "Comment"
{ "" { 1 1 } \Ga }
INPUT \-> COM
          \<< "DX " F
\->STR + " " + C +
" " + COM + TRAN
          \>>
        \>>
      \>>
    \>>
  C3 "N4Q"
  STN { { "NE1R"
    \<< "NE1R" CONT
    \>> } { "SECT"
    \<< "SECT" CONT
    \>> } { "WYN"
    \<< "BBSWYN" CONT
    \>> } { "KB1H"
    \<< "KB1H" CONT
    \>> } { "SALEM"
    \<< "SALEM" CONT
    \>> } }
  TRAN
    \<< EOL + XMIT
DROP
    \>>
  REC
    \<< 20 STIME
# 131d # 64d BLANK
PICT STO 0 \-> N
      \<<
        DO
          DO 1
SRECV DROP EOL
          UNTIL ==
          END W 1
SRECV DROP DROP W 3
SRECV DROP \-> S3
          \<<
            IF 'C3\=/
S3'
            THEN
              IF S3
"DX" POS 0 \=/
              THEN
660 .5 BEEP 990 .5
BEEP 13 SRECV DROP
DROP PICT # 0d N 6
* R\->B 2 \->LIST
# 131d # 6d BLANK
REPL PICT 21 SRECV
DROP "       " + 33
SRECV DROP DROP
PICT # 116d N 6 *
R\->B 2 \->LIST 4 SRECV
DROP 1 \->GROB REPL
              ELSE
PICT S3 18 SRECV
DROP + PICT # 83d N
6 * R\->B 2 \->LIST 7
SRECV DROP 5 SRECV
DROP DROP 5 SRECV
DROP + 1 \->GROB REPL
              END 1
\->GROB # 0d N 6 *
R\->B 2 \->LIST SWAP
REPL N 1 + 10 MOD
'N' STO { # 0d # 0d
} PVIEW
            END
          \>> CLEAR
        UNTIL 0
        END
      \>>
    \>>
  CST { { "SEND"
    \<< "Enter text"
{ "" { 1 1 } \Ga }
INPUT TRAN RALL
    \>> } REC {
"SH/D"
    \<< "SH/D " QUAL
TMENU HALT + TRAN 0
MENU REC
    \>> } { "DX"
    \<< DX REC
    \>> } RALL
SBRK { CON
    \<< "C " STN
TMENU HALT + TRAN 0
MENU RALL
    \>> } { DIS
    \<< SBRK "D" TRAN
RALL
    \>> } { "FO"
    \<< "FO BBSWYN"
TRAN RALL
    \>> } { "TIME"
    \<< DATE \-> D
      \<< TIME \-> T
        \<<
"DAYTIME " D
1000000 * 100 MOD
100000000 * D IP
100 MOD 10000 * + D
100 * IP 100 MOD
1000000 * + T IP
100 * + T 100 * IP
100 MOD + 0 FIX
\->STR + TRAN
        \>>
      \>>
    \>> } { "CONV"
    \<< "K" TRAN RALL
    \>> } { "BUCK"
    \<< "SH/BUCK "
"Call Sign:" { "" {
1 1 } \Ga } INPUT +
TRAN RALL
    \>> } { "QSL"
    \<< "SH/QSL "
"Call Sign:" { "" {
1 1 } \Ga } INPUT +
TRAN RALL
    \>> } }
  EOL ""
  IOPAR { 9600 0 1
1 3 1 }
END

*(eof)