'MasterMind Software offers this quick and dirty version of
'its Word for Windows Macro: AutoFax
'
'The full version is available in the MSWORD forum, Word for
'Windows library, as AUTOFAX!.ZIP
'
'To use THIS macro, please follow these directions:
'
'Set up a section of WIN.INI called [AutoFax]
'It should look like this:
'
'[AutoFax]
'WinFax Location=E:\PROGS\WINFAX\FAXMNG.EXE
'WinFax Port=WINFAX ON COM2:
'Printer Port=IBM LaserPrinter 4019 PS17 ON LPT1:
'
'This macro will read WIN.INI and check these values.
'AutoFax will fail if they do not exist.
'
'Replace "E:\PROGS\WINFAX\FAXMNG.EXE" with the full path and
'filename of your copy of WINFAX PRO.
'Replace "WINFAX ON COM2:" with the port name your modem uses
'Include the colon.
'Replace "IBM LaserPrinter 4019 PS17 ON LPT1:" with the port to which
'your actual printer is attached.  Include the colon.
'
'AutoFax MINI by MasterMind Software -- CompuServe 72630,555
'
'*******************************************************************

Sub MAIN
On Error Goto FINISHED

WINFAXLOCATION$ = GetProfileString$("AutoFax", "WinFax Location")
WINFAXLOCATION$ = UCase$(WINFAXLOCATION$)
WINFAXPORT$ = GetProfileString$("AutoFax", "WinFax Port")
WINFAXPORT$ = UCase$(WINFAXPORT$)
ORIGINALPORT$ = GetProfileString$("AutoFax", "Printer Port")
ORIGINALPORT$ = UCase$(ORIGINALPORT$)
FAXNUMBER$ = Left$(Selection$(), 14)

Dim DLG As UserDialog
Begin Dialog UserDialog  500, 150, "MasterMind -- AutoFax This Document"
	Text 25, 15, 150, 15, "&Recipient Name"
	Text 25, 45, 150, 15, "&Fax Number"
	TextBox 165, 15, 300, 20, .RECIPIENT
	TextBox 165, 40, 150, 20, .FAXNUMBER
	Text 40, 125, 430, 15, "Fax Number Defaults to First 14 Characters of Selection"
	PushButton 80, 80, 150, 25, "&Send"
 	CancelButton 280, 80, 150, 25
End Dialog
Redim DLG As UserDialog
DLG.RECIPIENT = RECIPIENT$
DLG.FAXNUMBER = FAXNUMBER$
VAR1 = Dialog(DLG)
RECIPIENT$ = DLG.RECIPIENT
FAXNUMBER$ = DLG.FAXNUMBER
If VAR1 = 0 Then Goto FINISHED

FilePrintSetup .Printer = WINFAXPORT$
Shell WINFAXLOCATION$, 0
ChanNumber = DDEInitiate("FAXMNG", "Transmit")
DDEPoke(ChanNumber, "Fax Number", FAXNUMBER$)
DDEPoke(ChanNumber, "Receiver", RECIPIENT$)
DDETerminate(ChanNumber)
Print "Faxing document to " ; RECIPIENT$ ; " at fax number FAXNUMBER$"
FilePrint .Type = 0, .NumCopies = "1", .Range = 0, .PrintToFile = 0, .Collate = 0, .FileName = ""	

FINISHED:
FilePrintSetup .Printer = ORIGINALPORT$
End Sub